{
  description = "Configuration flake for RandomCTF";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/release-25.05";
    home-manager = {
      url = "github:nix-community/home-manager/release-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-darwin = {
      url = "github:LnL7/nix-darwin";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, nix-darwin, home-manager, nix-index-database, ... } @ inputs:
    let
      mkNixosConfig = hostname: modules: nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = { inherit inputs; };
        inherit modules;
      };

      mkHomeConfig = username: system: modules: home-manager.lib.homeManagerConfiguration {
        pkgs = import nixpkgs { inherit system; };
        extraSpecialArgs = {
          inherit inputs;
          user = username;
        };
        inherit modules;
      };
    in {
      # Nixos Configurations
      nixosConfigurations = {
        randomctf = mkNixosConfig "randomctf" [ ./config/shared.nix ./config/omen.nix ];
        r330-media = mkNixosConfig "r330-media" [ ./config/media.nix ];
        sampledb-dev = mkNixosConfig "sampledb-dev" [ ./config/sampledb.nix ];
        r330-logging = mkNixosConfig "r330-logging" [ ./config/logging.nix ];
        mindforge = mkNixosConfig "mindforge" [ ./config/ai.nix ];
      };
      # Home-Manager Configurations

      homeConfigurations = {
        random = mkHomeConfig "random" "x86_64-linux" [
          ./home/headful-nixos.nix
          ./home/modules/development.nix
          ./home/modules/gui-apps.nix
          ./home/modules/hacking.nix
        ];

        sampledb = mkHomeConfig "sampledb" "x86_64-linux" [
          ./home/headless-nixos.nix
          ./home/modules/development.nix
        ];

        media = mkHomeConfig "media" "x86_64-linux" [ ./home/headless-nixos.nix ];
        logging = mkHomeConfig "logging" "x86_64-linux" [ ./home/headless-nixos.nix ];
        mindforge = mkHomeConfig "mindforge" "x86_64-linux" [ ./home/headless-nixos.nix ];
      };

      # Darwin Configuration

      darwinConfigurations."Jadens-MacBook-Air" = nix-darwin.lib.darwinSystem {
        system = "aarch64-darwin";
        specialArgs = { inherit inputs; };
        modules = [
          ./config/darwin.nix
          home-manager.darwinModules.home-manager {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.users.jadenmaxwell = import ./home/darwin.nix;
          }
        ];
      };

      homeConfigurations.jadenmaxwell = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-darwin";
        modules = [
          ./home/darwin.nix
        ];
      };
    };
}